/** 
* <h2>JDLFlowers_2009</h2>
* A graphic tool to create an illustration for a poster announcing the "<a href="http://journeesdulibre.bxlug.be">journees du libre 2009</a>".
* <h3>How to use:</h3>
* Click, hold, drag and release to draw a flower.<br />
* Flower size is determined by the dragging distance.<br />
* Flower color is determined by its position.<br />
* Reload the page to start over.<br />
* <br />
* &copy; Juego - Licence: <a href="http://www.gnu.org/copyleft/gpl.html">GNU General Public Licence</a>
*/

float _size = 60;
float dx, dy, px, py;
color couleur;
color blanc = #FFFFFF;

void setup() {
  size(640,480);
  background(255);
  smooth();
  colorMode(HSB, 100);
}

void draw() {
}

void mousePressed(){
  dx = mouseX;
  dy = mouseY;
}

void mouseReleased(){
  px = mouseX;
  py = mouseY;
  float dd = dist(dx, dy, px, py);
  
  //couleur = color( random(100), 100,50);
  couleur = color( map( mouseX, 0, width, 5, 60), 100, 100);
  
  tige(px, py, dd, width/2, height, couleur );
  flower(px, py, dd, int(random(6)+1), couleur );
}

void flower(float px, float py, float _size, int nb_branches, color c) {
  pushMatrix();
  translate(px, py);
  rotate(random(PI));
  noStroke();
  ellipseMode(CENTER);
  fill(c);
  ellipse(0, 0, _size, _size);
  fill(blanc);
  ellipse(0, 0, _size*0.9, _size*0.9);
  fill(c);
  rectMode(CENTER);
  float ang = PI/nb_branches;
  for(int i=0; i<nb_branches; i++) {
    rotate(ang);
    rect(0, 0, _size*0.8, _size*0.08);
  }
  fill(blanc);
  ellipse(0, 0, _size*0.3, _size*0.3);
  fill(c);
  ellipse(0, 0, _size*0.2, _size*0.2);
  popMatrix();
}

void tige(float px, float py, float _size, float ox, float oy, color c) {
  noFill();
  stroke(c);  
  strokeWeight(_size*0.05);
  bezier(ox, oy, ox, py, px, oy, px, py);
}